Hoe een 7-segments, 4-cijferig display met een gemeenschappelijke anode gebruiken?

Net als een aanvulling op het antwoord van Paul, schreef ik een kort programma om te laten zien hoe de 7-segments 4-cijferige weergave van zijn figuur te rijden:

Dit is eigenlijk een algemeen kathodescherm, dus het programma gaat ervan uit dat, evenals de specifieke bedrading van de figuur. Het interessante deel is de functie refresh_display() , die periodiek moet worden aangeroepen. Het algoritme is als volgt:

• rijd de 7 anodes met de juiste signalen voor een van de cijfers we willen laten zien
• zet HIGH op de output die de kathode van dat cijfer via de NPN-transistor
• wacht 2,5 ms (voor een vernieuwingsfrequentie van 100 Hz)
• stel LAAG in voor de kathoderegelinguitgang
• ga naar het volgende cijfer.

Opgemerkt moet worden dat het wachten gebeurt zonder de CPU te blokkeren, door met behulp van de techniek beschreven in de Knippert zonder Vertraging Arduino tutorial. Hier is het programma:

const int NB_DIGITS     = 4; //4-digit display
const int FIRST_ANODE   = 2; //anodes a..g on pins 2..8
const int FIRST_CATHODE = 9; //cathodes, right to left, on pins 9..12

// Digits to display, from right to left.
uint8_t digits[NB_DIGITS];

// Set all the used pins as outputs.
void init_display()
{
    for (int i = 0; i < 7; i++)
        pinMode(FIRST_ANODE + i, OUTPUT);
    for (int i = 0; i < NB_DIGITS; i++)
        pinMode(FIRST_CATHODE + i, OUTPUT);
}

// This should be called periodically.
void refresh_display()
{
   //Our 7-segment "font".
    static const uint8_t font[10] = {
        //abcdefg
        0b1111110,//0
        0b0110000,//1
        0b1101101,//2
        0b1111001,//3
        0b0110011,//4
        0b1011011,//5
        0b1011111,//6
        0b1110000,//7
        0b1111111,//8
        0b1111011 //9
    };

   //Wait for 2.5 ms before switching digits.
    static uint32_t last_switch;
    uint32_t now = micros();
    if (now - last_switch < 2500) return;
    last_switch = now;

   //Switch off the current digit.
    static uint8_t pos;
    digitalWrite(FIRST_CATHODE + pos, LOW);

   //Set the anodes for the next digit.
    pos = (pos + 1) % NB_DIGITS;
    uint8_t glyph = font[digits[pos]];
    for (int i = 0; i < 7; i++)
        digitalWrite(FIRST_ANODE + i, glyph & 1 << (6-i));

   //Switch digit on.
    digitalWrite(FIRST_CATHODE + pos, HIGH);
}

/***********************************************************************
 * Example usage.
 */

void setup()
{
    init_display();
}

void loop()
{
    uint32_t now = millis();

   //Change the number displayed every second.
    static uint32_t last_change;
    if (now - last_change >= 1000) {
        digits[3] = digits[2];
        digits[2] = digits[1];
        digits[1] = digits[0];
        digits[0] = (digits[0] + 1) % 10;
        last_change = now;
    }

    refresh_display();
}

Paul gaf een link naar een tutorial on Parallax dat suggereert het gebruik van de Multiplex7Seg Arduino-bibliotheek. Die bibliotheek is meer algemeen dan de voorbeeldcode hierboven, omdat het geen aannames maakt over de gebruikte pinnen. Maar de grote verschil tussen de bibliotheek en deze code ligt in de manier waarop de timings worden beheerd:

• De bibliotheek wordt aangestuurd door de overloop-interrupt Timer 2. Dit zou zorg voor een zeer constante timing, ten koste van één timer opgedragen aan deze baan.
• De bovenstaande code is afhankelijk van de gebruiker die vaak refresh_display() aanroept genoeg. Het vereist geen speciale hardwarebronnen, maar het werkt niet goed met programma's die te lang duren om loop() : it zal het niet leuk vinden als je delay() aanroept.